본문 바로가기
스마트러닝/엑셀과 구글스프레드시트

엑셀 몇가지 팁

by 민서아빠(과학사랑) 2013. 1. 11.

엑셀 학생 이름 사이에 동그라미 넣기 - 개인정보보호

예) 김정식 -> 김O식

함수 : 김정식이라는 이름이 A1셀에 있는 경우

=LEFT(A1,1)&"O"&RIGHT(A1,1)

 

엑셀을 이용할때 필요한 몇가지 고급팁 정리(pc사랑 3월호 참고)
1. rank 함수로 처리할 수 없는 동점자 석차까지 구하기

석차 구하기
=RANK(E11,$E$4:$E$12)+SUM((E11=$E$4:$E$12)*(C11<$C$4:$C$12))


=RANK(석차,석차범위)+SUM((석차=석차범위)*(국어점수<국어점수범위))

rank함수로 석차를 구한다음 거기에다가
sum 함수를 이용해서 조건에 맞는 수를 더한다.
여기에서는 석차가 같으면서 국어 점수가 국어점수 범위보다  낮은수 만큼 반복해서 더한다.
배열함수이므로 반드시 CTRL+SHIFT+ENTER 을 눌러 주어야 정상적으로 적용된다.

2. 이름중복되었는지 확인하기
가끔 이름이나 내용이 중복되었는지 확인해야 될 필요가 있다. 그럴때 사용

이름이 중복되는지 확인하는 방법
=IF(COUNTIF($B$4:$B$12,B4)>1,"중복","")

=IF(COUNTIF(이름범위,이름)>1,"중복","")

이름범위에서 이름과 같은것이 몇개 있는지 countif 함수를 이용해서 찾아낸다

조건부 서식을 이용해서 중복된 경우 색 바꾸는 방법
<조건부 서식에>
수식어 : =COUNTIF($B$4:$B$12,B4)>1


3. 등수에 맞는 이름과 점수 나타내기

등수에 맞는 점수 찾기

=INDEX($B$4:$B$12,MATCH(B20,$F$4:$F$12,0))

match 함수를 이용해서 범위 안에서 같은 숫자가 몇번째 있는 지 확인
index 함수를 이용해서 범위 내에서 몇번째 있는 이름 출력


그리고 반드시 CTRL+SHIFT+ENTER 을 눌러 주어야 정상적으로 작동한다.

4. 중복된 이름을 제외한 총 인원수

=SUM(1/COUNTIF(B4:B12,B4:B12))

이름목록에서 자신의 이름이 몇 개인지 센후 중복된 이름수로 나누어서 그것을 모두 더한다.
결과적으로 이름이 4번 나오면
1/4+1/4+1/4+1/4 = 1 이 되어 같은 이름은 1명으로 계산된다.

5. 성적 분포안에 포함되는 인원수 세기
분포되어 있는 빈도수 측정
즉 범위이내에 들어있는 숫자 카운트
단 값들은 정수이어야 한다.

=FREQUENCY($E$4:$E$12,C34:C38)

배열입력 을 해야 함
즉 c34,c38까지 선택을 한다음 위 명령어를 넣어줌
그리고 나서 CTRL+SHIFT+ENTER  하면 됨

6. 이름이 같은 경우 주민등록까지 이용하여 구분하기

=INDEX(C1:C39,MATCH(J8&K8,A1:A39&B1:B39,0),0)

MATCH 함수에서 한셀만 찾는 것이 아니라 두셀을 & 로 연결해서 찾는다.
즉 MATCH(이름&주민번호,이름열&주민번호열,0)
이런식이다.